Loading files
This file is pinned to the selected release. Download the original to open it in your design tool.
2dec9d849This file is pinned to the selected release. Download the original to open it in your design tool.
WT = 2; /* wall thickness */
CW = 117; /* cavity width */
CH = 40; /* cavity height */
CD = 75; /* cavity depth */
FW = 10; /* flange width */
FT = 4; /* flange thickness */
MHD = 3; /* mounting hole diameter */
MHCD = 6; /* mounting hole countersink diameter */
MHCA = 90; /* mounting hole countersink angle */
MHO = 15; /* mounting hole offset */
CHW = 20; /* cable hole width */
CHH = 20; /* cable hole height */
CHCR = 3; /* cable hole corner radius */
MHCSDT = (MHCD - MHD)/2/tan(MHCA/2);
echo("Mounting hole countersink depth:", MHCSDT);
module flange() {
difference() {
cube([FW,FT,CD+WT]);
/* mounting holes: */
for (zoffset = [MHO,(CD+WT)/2,CD+WT-MHO]) {
translate([FW/2,0,zoffset]) rotate([-90,0,0]) {
/* countersink: */
cylinder(d1=MHCD, d2=MHD, h=MHCSDT, $fn=20);
/* hole: */
cylinder(d=MHD, h=FT, $fn=20);
}
}
}
}
/* back wall: */
difference() {
cube([CW+2*WT,CH+WT,WT]);
/* cable hole: */
translate([(CW+2*WT-CHW)/2,(CH+WT-CHH)/2,0]) hull() {
for (x = [CHCR,CHW-CHCR]) {
for (y = [CHCR,CHH-CHCR]) {
translate([x,y,0]) cylinder(r=CHCR, h=WT, $fn=20);
}
}
}
}
/* left wall: */
cube([WT,CH+WT,CD+WT]);
/* right wall: */
translate([CW+WT,0,0]) cube([WT,CH+WT,CD+WT]);
/* bottom wall: */
cube([CW+2*WT,WT,CD+WT]);
/* left flange: */
translate([-FW,CH+WT-FT,0]) flange();
/* right flange: */
translate([CW+2*WT,CH+WT-FT,0]) flange();